home *** CD-ROM | disk | FTP | other *** search
/ Amiga Collections: Camelot / Camelot 043 (1989-06)(Swedish User Group of Amiga)(SE)(PD)[WB].zip / Camelot 043 (1989-06)(Swedish User Group of Amiga)(SE)(PD)[WB].adf / printfx / cst.a < prev    next >
Text File  |  1989-06-08  |  4KB  |  185 lines
  1. *
  2. * C initial startup procedure under AmigaDOS
  3. * Special stripped version !!
  4. * 
  5.  
  6.     INCLUDE    "exec/types.i"
  7.     INCLUDE    "exec/libraries.i"
  8.     INCLUDE    "libraries/dos.i"
  9.     INCLUDE    "libraries/dosextens.i"
  10.     INCLUDE    "exec/funcdef.i"
  11.     INCLUDE    "exec/exec_lib.i"
  12.     INCLUDE    "libraries/dos_lib.i"
  13.  
  14. AbsExecBase    EQU    4
  15.  
  16.     xdef    _XCEXIT        exit(code) is standard way to leave C.
  17.  
  18.     xref    _LinkerDB    linker defined base value
  19.     xref    __BSSBAS    linker defined base of BSS
  20.     xref    __BSSLEN    linker defined length of BSS
  21.  
  22.     csect    text,0,0,1,2    any xref's after this are 16-bit reloc
  23.  
  24.     xref    __main        Name of C program to start with.
  25.  
  26. start:
  27.     movem.l d1-d6/a0-a6,-(a7)
  28. REGSIZE    EQU    (6+7)*4
  29.     lea    REGSIZE(a7),A5        determine old stack pointer
  30.     move.l    a0,a2            save command pointer
  31.     move.l    d0,d2            and command length
  32.     lea    _LinkerDB,a4        load base register
  33.  
  34.     lea    __BSSBAS,a0        get base of BSS
  35.     moveq    #0,d1
  36.     move.l    #__BSSLEN,d0        get length of BSS in longwords
  37.     bra.s    clr_lp            and clear for length given
  38. clr_bss move.l    d1,(a0)+
  39. clr_lp    dbf    d0,clr_bss
  40.  
  41.     move.l    AbsExecBase.W,a6
  42.     move.l    a6,_SysBase(A4)
  43.     move.l    a7,__StackPtr(A4)    Save stack ptr
  44.  
  45. *------ get the address of our task
  46.     suba.l    a1,a1
  47.     jsr    _LVOFindTask(a6)
  48.     move.l    d0,a3
  49.  
  50. *------ are we running as a son of Workbench?
  51.     move.l    pr_CurrentDir(A3),_curdir(A4)
  52.     tst.l    pr_CLI(A3)
  53.     beq    exit4            Not supported
  54.  
  55.     move.l    a5,D0            Get top of stack
  56.     sub.l    4(a5),D0        compute bottom 
  57.     move.l    D0,__base(A4)        save for stack checking
  58.  
  59. *------ attempt to open DOS library:
  60.     lea    DOSName(pc),A1
  61.     moveq.l    #0,D0
  62.     jsr    _LVOOpenLibrary(a6)
  63.     move.l    D0,_DOSBase(A4)
  64.     bne.s    DOSok
  65.     moveq.l    #100,d0
  66.     bra.s    exit2
  67. DOSok
  68. *------ find command name:
  69.     move.l    pr_CLI(a3),a0
  70.     add.l    a0,a0            bcpl pointer conversion
  71.     add.l    a0,a0
  72.     move.l    cli_CommandName(a0),a1
  73.     add.l    a1,a1            bcpl pointer conversion
  74.     add.l    a1,a1
  75.  
  76. *------ collect parameters:
  77.     move.l    d2,d0            get command line length
  78.     moveq.l    #0,d1
  79.     move.b    (a1)+,d1
  80.     move.l    a1,__ProgramName(A4)
  81.     add.l    d1,d0            add length of command name
  82.     addq.l    #1,d0            allow for space after command 
  83.  
  84.     clr.w    -(A7)            set null terminator for command line
  85.     addq.l    #1,D0            force to even number of bytes
  86.     andi.w    #$fffe,D0        *(round up)
  87.     sub.l    D0,A7            make room on stack for command line
  88.     subq.l    #2,D0
  89.     clr.w    0(A7,D0)
  90.  
  91. *------ copy command line onto stack
  92.     move.l    d2,d0            get command line length
  93.     subq.l    #1,d0
  94.     add.l    d1,d2
  95.  
  96. copy_line:
  97.     move.b    0(A2,D0.W),0(A7,D2.W)    copy command line to stack
  98.     subq.l    #1,d2
  99.     dbf    d0,copy_line
  100.     move.b    #' ',0(a7,d2.w)        add space between command and parms
  101.     subq.l    #1,d2
  102.  
  103. copy_cmd:
  104.     move.b    0(a1,d2.w),0(a7,d2.w)    copy command name to stack
  105.     dbf    d2,copy_cmd
  106.     move.l    A7,A1
  107.     move.l    A1,-(A7)        push command line address
  108.  
  109.     lea.l    Asterix(pc),a0
  110.     move.l    a0,d1
  111.     move.l    #MODE_OLDFILE,d2
  112.     move.l    _DOSBase(A4),a6
  113.     jsr    _LVOOpen(a6)
  114.     move.l    d0,_ConOut(a4)
  115.     beq.s    exit4
  116.  
  117. main    jsr    __main(PC)        call C entrypoint
  118. *    moveq.l #0,d0            set successful status
  119.     bra.s    exit2
  120.  
  121.  
  122. _XCEXIT:
  123.     move.l    4(SP),d0        extract return code
  124. exit2:
  125.     move.l    d0,-(a7)
  126.     move.l    __ONEXIT(A4),d0        exit trap function?
  127.     beq.s    exit3
  128.     move.l    d0,a0
  129.     jsr    (a0)
  130.  
  131. exit3    move.l    _ConOut(a4),d1
  132.     move.l    _DOSBase(A4),a6
  133.     jsr    _LVOClose(a6)
  134.  
  135. exit4    move.l    AbsExecBase.W,a6
  136.     move.l    _DOSBase(A4),a1
  137.     jsr    _LVOCloseLibrary(a6)    close Dos library
  138.  
  139. exitToDOS:
  140.     move.l    (a7)+,d0
  141.     movea.l    __StackPtr(a4),SP    restore stack ptr
  142.     movem.l    (a7)+,d1-d6/a0-a6
  143.     rts
  144.  
  145. DOSName    dc.b    'dos.library',0
  146. Asterix    dc.b    '*',0
  147.  
  148. *-----------------------------------------------------------------------
  149.  
  150.     csect    __MERGED,1,,2,2
  151.  
  152.     xref    _DOSBase
  153.  
  154.     xdef    _SysBase,_LoadAddress
  155.     xdef    _curdir,__mbase,__mnext,__msize,__tsize
  156.     xdef    __oserr,__OSERR,__FPERR,__SIGFPE,__ONERR,__ONEXIT,__ONBREAK
  157.     xdef    __SIGINT,__ECS
  158.     xdef    __ProgramName,__StackPtr,__base
  159.     xdef    _ConOut
  160.  
  161. _ConOut        ds.l    1
  162. __base        ds.l    1        base of stack
  163. __mbase        ds.l    1        base of memory pool
  164. __mnext        ds.l    1        next available memory location
  165. __msize        ds.l    1        size of memory pool
  166. __tsize        ds.l    1        total size?
  167. __oserr        equ    *
  168. __OSERR        ds.l    1
  169. __FPERR        ds.l    1
  170. __SIGFPE    ds.l    1
  171. __SIGINT    ds.l    1
  172. __ONERR        ds.l    1
  173. __ONEXIT    ds.l    1
  174. __ONBREAK    ds.l    1
  175. __ECS        ds.l    1        extended character set flag
  176. _curdir        ds.l    1
  177. _console_dev    ds.l    1
  178. _SysBase    ds.l    1
  179. _LoadAddress    ds.l    1        program load address
  180. __StackPtr    ds.l    1
  181. __ProgramName    ds.l    1
  182.  
  183.     END
  184.     
  185.